【MQL5】基本のキ→移動平均線の種類

(4つ前の価格 + 3つ前の価格 + 2つ前の価格 + 1つ前の価格 + 直近の価格) ÷ 期間n

前回のEMA + 平滑化指数α × (直近の価格 - 前回のEMA)

※平滑化指数α = 2 ÷ (期間n + 1)

((前回のSMMA × (期間n - 1) + 直近の価格) ÷ 期間n

((直近の価格 × 期間n) + (1つ前の価格 × n-1) + ・・・ + (4つ前の価格 × n-4)) ÷ (n + (n-1) + ・・・ + (n-4))

#property indicator_buffers   4                 // 指標計算に使用するバッファの数を指定（指標バッファ）
#property indicator_plots     4                 // 指標のプロット数を指定

// プロット１の定義
#property indicator_type1     DRAW_LINE         // 描画タイプ
#property indicator_color1    clrDodgerBlue     // 青線

// プロット２の定義
#property indicator_type2     DRAW_LINE         // 描画タイプ
#property indicator_color2    clrYellow         // 黄線

// プロット３の定義
#property indicator_type3     DRAW_LINE         // 描画タイプ
#property indicator_color3    clrRed            // 赤線

// プロット４の定義
#property indicator_type4     DRAW_LINE         // 描画タイプ
#property indicator_color4    clrWhite          // 白線

double m_val1[], m_val2[], m_val3[], m_val4[];  // 指標バッファと紐づける動的配列を宣言
int m_handle1, m_handle2, m_handle3, m_handle4; // 各指標のハンドル
int m_bars_calculated1 = 0;
int m_bars_calculated2 = 0;
int m_bars_calculated3 = 0;
int m_bars_calculated4 = 0;

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
   // 動的配列と指標バッファを紐付け
   SetIndexBuffer(0, m_val1, INDICATOR_DATA);
   SetIndexBuffer(1, m_val2, INDICATOR_DATA);
   SetIndexBuffer(2, m_val3, INDICATOR_DATA);
   SetIndexBuffer(3, m_val4, INDICATOR_DATA);
   
   // 動的配列変数を初期化。（0.0を設定）
   ArrayInitialize(m_val1, 0.0);
   ArrayInitialize(m_val2, 0.0);
   ArrayInitialize(m_val3, 0.0);
   ArrayInitialize(m_val4, 0.0);
   
   m_handle1 = iMA(_Symbol, PERIOD_CURRENT, 5, 0, MODE_SMA, PRICE_CLOSE);
   m_handle2 = iMA(_Symbol, PERIOD_CURRENT, 5, 0, MODE_EMA, PRICE_CLOSE);
   m_handle3 = iMA(_Symbol, PERIOD_CURRENT, 5, 0, MODE_SMMA, PRICE_CLOSE);
   m_handle4 = iMA(_Symbol, PERIOD_CURRENT, 5, 0, MODE_LWMA, PRICE_CLOSE);
      
   return(INIT_SUCCEEDED);
  }
  
void OnDeinit(const int reason)
  {
   if (m_handle1 != INVALID_HANDLE){
      IndicatorRelease(m_handle1);
   }
   if (m_handle2 != INVALID_HANDLE){
      IndicatorRelease(m_handle2);
   }
   if (m_handle3 != INVALID_HANDLE){
      IndicatorRelease(m_handle3);
   }
   if (m_handle4 != INVALID_HANDLE){
      IndicatorRelease(m_handle4);
   }
  }

//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   m_bars_calculated1 = CreateBuffer(rates_total, prev_calculated, m_bars_calculated1, m_handle1, m_val1);
   m_bars_calculated2 = CreateBuffer(rates_total, prev_calculated, m_bars_calculated2, m_handle2, m_val2);
   m_bars_calculated3 = CreateBuffer(rates_total, prev_calculated, m_bars_calculated3, m_handle3, m_val3);
   m_bars_calculated4 = CreateBuffer(rates_total, prev_calculated, m_bars_calculated4, m_handle4, m_val4);
   
   return(rates_total);
  }

int CreateBuffer(const int rates_total,
                 const int prev_calculated, 
                 const int bars_calculated,
                 const int handle,
                 double &values[])
{
   int result = 0;
   int values_to_copy;                       // iMAから複製された値の数
   int calculated = BarsCalculated(handle);  // 指標で計算された値の数

   if (calculated > 0) {
      // 次のいずれかに該当する場合
      // 初めてOnCalculated()が実行された（prev_calculated == 0）
      // iMA指標の数が変わった（calculated != m_bars_calculated）
      // 価格履歴で変動があった（rates_total > prev_calculated+1）
      if(prev_calculated == 0 || calculated != bars_calculated || rates_total > prev_calculated+1) {
         if (calculated > rates_total) {
            values_to_copy = rates_total;
         }
         else {
            values_to_copy = calculated;
         }
      }
      else {
         values_to_copy = rates_total - prev_calculated + 1;
      }
      
      FillArrayFromBuffer(values, 0, handle, values_to_copy);
      
      result = calculated;
   }
   
   return(result);
}

bool FillArrayFromBuffer(double &values[], 
                         const int iShift, 
                         const int iHandle, 
                         const int iCopyAmount)
{
   bool bResult = false;

   ResetLastError();
   
   if (CopyBuffer(iHandle, 0, -0, iCopyAmount, values) < 0) {
      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());
   }
   else {
      bResult = true;
   }
   
   return(bResult);
}